Here's the updated version of using rib archives of particles on a second particle system:

- First archive your particle system using the archiver slim thingy. (Gives you the option of keeping shaders)

- Make your new particle system, template the particle object.
 Add a RibBox to it that reads:

   [mel "return_stuff()"]

- In the script editor run the following mel (obviously change the name of the ribs to use)

////////////////////////////////////////////////////////////////////////////////////
 
 global proc string TM_paddedNumber( int $number, int $padding )
{
   string $num = $number;
   while (size($num) < $padding)
   {
       $num = ("0"+$num);
   }
   return $num;
}


 global proc string return_stuff()
{

   int $num_particles = `getAttr particleShape1.count`;
   float $pos[];
   float $rot[];
   float $born[];


   $frm = `currentTime -query`;

   string $rib_syntax = "";

   for($i=0;$i<$num_particles;$i++)
   {
       $pos = `particle -order $i -attribute position -q particleShape1`;
       $rot = `particle -order $i -attribute velocity -q particleShape1`;
       $born = `particle -order $i -attribute birthTime -q particleShape1`;
    
       int $bornF = $born[0];

       int $bornFStep = $frm - ($bornF * 24);

       string $ribStep = `TM_paddedNumber $bornFStep 4`;
 

       $rib_syntax += ("AttributeBegin\n");
       $rib_syntax += ("ConcatTransform [");
       $rib_syntax +=     ("1 0 0 0 0 1 0 0 0 0 1 0 " + $pos[0] + " " + $pos[1] + " " + $pos[2] + " 1" + "]\n");
       $rib_syntax += ("Rotate "+ $rot[0] + " " + $rot[1] + " " + $rot[2] + " 0\n");
       $rib_syntax += ("ReadArchive \"rib/stringy1/stringy1.particle1." + $ribStep + ".rib\"\n");
       $rib_syntax += ("AttributeEnd\n");
   }

   return $rib_syntax;

}


///////////////////////////////////////////////////////////////////////////


**NB - this only works if you render it from the live scene (because it is referencing global procedures), but it should be pretty quick. You might want to try replacing ReadArchive for DelayedReadArchive for even more memory improvement. It should be possible to adjust speed or scaling by adjusting the "($bornF * 24)" bit, or by adding a Scale line similar to the Rotate line.

Its a start anyway - [Stephen says he has a pdb file reader thingy anyway if you need to do this at Hensons.]

done it!